Автоматическое подключение принтеров

[CrazyRaven]

не могли бы дать ссылки на такую документацию?

[servilat Профиль]

добрый день!!

предлагаю скрипт по динамическому подключению принтеров в домене.
для правильного принтера по умолчанию надо пробить размещения рабочих станций в АД!!! (параметр размещение принтеров не применяеться!!!)
примерное описание
1.скрипт подключает ВСЕ принтера опубликовванныйе в АД и являющиеся доступными в момент подключения.
2.скрипт получает массивы с АД принт серверов 1.Print_Server(рабстанцияпринтера, принтер) и рабочих станций 2.Comp_Location(рабстанцияпринтера, размещениерабстанц) далее из 2х предыдущих массивов скрипт генерит еще два масива 1.Printers_Location(принтер,размещение,рабстанцияпринтера) и 2.Comp_Printer_Default(рабстанция(все с АД), принтер,рабстанцияпринтера)
3.подключаем принтера перебором в масиве Print_Server - масив полученный с АД.
4.устанавливаем дефолтным по масиву Comp_Printer_Default - установиться последний принтер в масиве по совпадению размещений рабочих станций.
(т.е. если в одном размещении несколько рабстанцияпринтера дефалтный будет последний)
5.статика по размещению SetPrinterDefaultLocationStatic "ws9", "ws3" (на всех компах с размещением ws9 принтером по умолчанию станет последний принтер с размешения ws3
6. статика комп-комп SetPrinterDefaultStatic "dfmailcl", "ws3" (на компе dfmailcl принтером по умолчанию будет принтер с ws3.

сам скрипт часть логон скрипта, и не привязан к конкретному домену.

On Error Resume Next

'ПЕРЕМЕННЫЕ
'модуль Connect_Net_Printers
Dim Current_Comp_Name, Current_Comp_Location
Dim objRecordSet_Printers, objRecordSet_Computers
Dim Print_Server()
Dim Comp_Location()
'динамически созданные массивы
Dim Printers_Location()
Dim Comp_Printer_Default()


Set WshShell = WScript.CreateObject("WScript.Shell")
Set WSHNetwork = WScript.CreateObject("WScript.Network")
Set colDrives = WSHNetwork.EnumNetworkDrives
Set fso=WScript.CreateObject("Scripting.FileSystemObject")
set wshProcEnv = wshShell.environment("process")


Connect_Net_Printers()


'++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
Sub Connect_Net_Printers()
On Error Resume Next

'========================================================================================
'определение днс суфикса домена
Set objSysInfo = CreateObject("ADSystemInfo")
strUserDN = objSysInfo.UserName
strCompDN = objSysInfo.ComputerName
Set objUser = GetObject("LDAP://" & strUserDN)
Set objComp = GetObject("LDAP://" & strCompDN)
Full_DC_Name="'LDAP://" & mid(strCompDN,InStr(strCompDN,"DC="),len(strCompDN)) & "'"
'========================================================================================
Current_Comp_Name =objComp.cn
Current_Comp_Location=objComp.location

Const ADS_SCOPE_SUBTREE = 2
Set objConnection = CreateObject("ADODB.Connection")
objConnection.Provider = ("ADsDSOObject")
objConnection.Open "Active Directory Provider"

'========================================================================================
'запрос данных с АД по принтерам
Set objCommand_Printers = CreateObject("ADODB.Command")
objCommand_Printers.ActiveConnection = objConnection
objCommand_Printers.Properties("Page Size") = 1000
objCommand_Printers.Properties("Searchscope") = ADS_SCOPE_SUBTREE
objCommand_Printers.CommandText = "Select printername,shortservername from " & Full_DC_Name & " where objectcategory='printQueue' "
Set objRecordSet_Printers = objCommand_Printers.Execute
objRecordSet_Printers.MoveFirst

'генерим масив принт серверов
ReDim Print_Server(1, objRecordSet_Printers.RecordCount-1)
P_S=0
Do Until objRecordSet_Printers.EOF
Print_Server(0, P_S)=objRecordSet_Printers.Fields("shortservername").Value
Print_Server(1, P_S)=objRecordSet_Printers.Fields("printername").Value
objRecordSet_Printers.MoveNext
P_S=P_S+1
Loop

'эта хрень выводит на экран список рабочая станция имя принтера юзаеться при настройке
's="Все принтера с АД:" & CHR(10) & "___________________________________" & CHR(10)
'For i=0 to objRecordSet_Printers.RecordCount-1
's=s & Print_Server(0, i) & " | " & Print_Server(1, i) & CHR(10)
'next
'msgbox s



'========================================================================================
'запрос с ад компов размещений и версий виндовс
Set objCommand_Computers = CreateObject("ADODB.Command")
objCommand_Computers.ActiveConnection = objConnection
objCommand_Computers.Properties("Page Size") = 1000
objCommand_Computers.Properties("Searchscope") = ADS_SCOPE_SUBTREE
'===================================================================
'ТОЛЬКО ХП
'objCommand_Computers.CommandText = "SELECT name, location, operatingSystemVersion FROM " & Full_DC_Name & " WHERE objectClass='computer' AND " & "operatingSystemVersion = '5.1 (2600)'"
'все
objCommand_Computers.CommandText = "SELECT name, location, operatingSystemVersion FROM " & Full_DC_Name & " WHERE objectClass='computer'"
'===================================================================
Set objRecordSet_Computers = objCommand_Computers.Execute
objRecordSet_Computers.MoveFirst

'генерим масив рабочая станция размещение опер систем
ReDim Comp_Location(2, objRecordSet_Computers.RecordCount-1)
C_L=0
Do Until objRecordSet_Computers.EOF
Comp_Location(0, C_L)=objRecordSet_Computers.Fields("name").Value
Comp_Location(1, C_L)=objRecordSet_Computers.Fields("location").Value
Comp_Location(2, C_L)=objRecordSet_Computers.Fields("operatingSystemVersion").Value
objRecordSet_Computers.MoveNext
C_L=C_L+1
Loop


'эта хрень выводит список компов с ад имя размещение опер сустем юзаеться при настройке скрипта
's="Все компьютеры с АД:" & CHR(10) & "___________________________________" & CHR(10)
'For j=0 to objRecordSet_Computers.RecordCount-1
's=s & Comp_Location(0, j) & " | " & Comp_Location(1, j) & " | " & Comp_Location(2, j) & CHR(10)
'next
'msgbox s

'========================================================================================


'генерим масив расположения принтеров на основе 2х предыдущих масивов
ReDim Printers_Location(2,objRecordSet_Printers.RecordCount-1)
For i=0 to objRecordSet_Printers.RecordCount-1
For j=0 to objRecordSet_Computers.RecordCount-1
If UCase(Print_Server(0, i))=UCase(Comp_Location(0, j)) then
Printers_Location(0, i)=Print_Server(1, i)
Printers_Location(1, i)=Comp_Location(1, j)
Printers_Location(2, i)=Comp_Location(0, j)
end if
next
next


'эта хрень выводит на экран расположения принтеров юзаеться при настройке
's="Размещение принтеров по отделам:" & CHR(10) & "___________________________________" & CHR(10)
'For i=0 to objRecordSet_Printers.RecordCount-1
's=s & Printers_Location(0, i) & " | " & Printers_Location(1, i) & " | " & Printers_Location(2, i) & CHR(10)
'next
'msgbox s


'генерим принтеров по умолчанию
ReDim Comp_Printer_Default(2, objRecordSet_Computers.RecordCount-1)
For j=0 to objRecordSet_Computers.RecordCount-1
For i=0 to objRecordSet_Printers.RecordCount-1
If UCase(Printers_Location(1, i))=UCase(Comp_Location(1, j)) then
Comp_Printer_Default(0, j)=Comp_Location(0, j)
Comp_Printer_Default(1, j)=Printers_Location(0, i)
Comp_Printer_Default(2, j)=Printers_Location(2, i)
end if

If UCase(Printers_Location(2, i))=UCase(Comp_Location(0, j)) then
Comp_Printer_Default(0, j)=Comp_Location(0, j)
Comp_Printer_Default(1, j)=Printers_Location(0, i)
Comp_Printer_Default(2, j)=Printers_Location(2, i)
exit for
end if

next
next

'выводит на табло компклиент принтер имя комп сервер неюзаеться
's="Принтера используемые по умолчанию:" & CHR(10) & "___________________________________" & CHR(10)
'For j=0 to objRecordSet_Computers.RecordCount-1
'if Comp_Printer_Default(0, j)="" then
'else
' s=s & Comp_Printer_Default(0, j) & " | " & Comp_Printer_Default(1, j) & " | " & Comp_Printer_Default(2, j) & CHR(10)
'end if
'next
'msgbox s

'подключение принтеров
For i=0 to objRecordSet_Printers.RecordCount-1
if UCase(Current_Comp_Name) = UCase(Print_Server(0, i)) then
else
WSHnetwork.AddWindowsPrinterConnection "\\" & UCase(Print_Server(0, i)) & "\" & UCase(Print_Server(1, i))
end if
next


'установка принтеров по умолчанию
'приоритет имеет локально поделюченный принтер (для переопределения нелокального используеться статика)
For j=0 to objRecordSet_Computers.RecordCount-1
if UCase(Comp_Printer_Default(0, j))=UCase(Current_Comp_Name) then
if UCase(Comp_Printer_Default(0, j))=UCase(Comp_Printer_Default(2, j)) then
WSHnetwork.SetDefaultPrinter UCase(Comp_Printer_Default(1, j))
else
WSHnetwork.SetDefaultPrinter "\\" & UCase(Comp_Printer_Default(2, j)) & "\" & UCase(Comp_Printer_Default(1, j))
end if
else
end if
next



'=======================================================вызов статических модулей=======================================================
'установка дефаултом по размещениям компы с размещением равным параметру 1, установят себе дефаултом принтер из размещения 2го параметра(последний из масива)
'все компы переключаем на серверную
SetPrinterDefaultLocationStatic "ws9", "ws3"


'конкретно по компам. принтер с параметра 2 станет дефолтным на компе. параметр 1
'комп буха переключаеться на комп програмера
'SetPrinterDefaultStatic "ws5", "ws1"
'комп програмера переключаеться на секретаря
'SetPrinterDefaultStatic "ws9", "ws3"
SetPrinterDefaultStatic "ws17", "ws3"
SetPrinterDefaultStatic "dfmailcl", "ws3"
SetPrinterDefaultStatic "fksedcl", "ws12"

End Sub




'========================================================статика. модули===========================================================
'установка принтеров по умолчанию. статика наслучай выхода из строя принтеров или окончания тонера или еще че нить...
'функция SetPrinterDefaultStatic(компутер, принтер_сервер) -юзаеться комп комп
Sub SetPrinterDefaultStatic(Workstation, Print_Server_Static)
On Error Resume Next
if UCase(Workstation)=UCase(Current_Comp_Name) then
'тоесть этот ком в списке статических есть знач буде применять статическое назначение дефалтного принтера
For i=0 to objRecordSet_Printers.RecordCount-1
if UCase(Print_Server_Static)=UCase(Print_Server(0, i)) then
WSHnetwork.SetDefaultPrinter "\\" & UCase(Print_Server(0, i)) & "\" & UCase(Print_Server(1, i))
end if
next
else
End if
End Sub


'функция SetPrinterDefaultLocationStatic(компьютер(размещение), принт_сервер(размещение)) -юзаеться локатион локатион
Sub SetPrinterDefaultLocationStatic(Workstation_Location, Print_Server_Static_Location)
On Error Resume Next
'определение размещения Print_Server_Static_Location
For j=0 to objRecordSet_Computers.RecordCount-1
if UCase(Comp_Location(0, j))=UCase(Print_Server_Static_Location) then
Location_Serv_Printer=Comp_Location(1, j)
end if
next

'определение размещения Workstation_Location
For j=0 to objRecordSet_Computers.RecordCount-1
if UCase(Comp_Location(0, j))=UCase(Workstation_Location) then
if UCase(Current_Comp_Location)=UCase(Comp_Location(1, j)) then
'размещение текущей рабочей станции совпало с указанным в параметре вызова процедуры
'ищем принтер по серв принтеру
For i=0 to objRecordSet_Printers.RecordCount-1
if UCase(Printers_Location(1, i))=UCase(Location_Serv_Printer) then
if UCase(Print_Server_Static_Location)=UCase(Print_Server(0, i)) then
WSHnetwork.SetDefaultPrinter "\\" & UCase(Print_Server(0, i)) & "\" & UCase(Print_Server(1, i))
End if
end if
next
end if
end if
next
End Sub

[neos Профиль СайтICQ]

Подскажите по скрипту подключения принтера с принтсервером.
Воспользовался скриптом от ABat
Вроде как все хорошо, но...
У меня есть 2 принтсервера с принтерами, которые тоже надо подключать.
Просто у обычных разшареных дрова хаваются, а вот через принтсервер нужно указывать дрова.
Можно это сделать скриптами?